mirror of
https://github.com/neovim/neovim.git
synced 2026-01-03 01:46:31 +10:00
ab20681c52
This reverts commits:
- 6b652a785033fd4164e049492a7327c1ed7c3e5f
- 2f689d5abde0ccddca9e20d8c93a0299bd054e32
- a025a46d4169587145fb54f04af349cd05cb6122
Several email addresses that are known to be valid caused bounces
due to an issue with my email setup. The previous commits incorrectly
marked these addresses as invalid. So revert the whole thing again.
62d8f3dab5
N/A patch:
vim-patch:2f689d5: runtime: mark more invalid email addresses
Co-authored-by: Christian Brabandt <cb@256bit.org>
41 lines
1.6 KiB
VimL
41 lines
1.6 KiB
VimL
" vim compiler file
|
|
" Compiler: cppcheck (C++ static checker)
|
|
" Maintainer: Vincent B. (twinside@free.fr)
|
|
" Last Change: 2025 Nov 06 by @Konfekt
|
|
|
|
if exists("current_compiler") | finish | endif
|
|
let current_compiler = "cppcheck"
|
|
|
|
let s:cpo_save = &cpo
|
|
set cpo&vim
|
|
|
|
let s:slash = has('win32')? '\' : '/'
|
|
|
|
if !exists('g:c_cppcheck_params')
|
|
let g:c_cppcheck_params = '--verbose --force --inline-suppr'
|
|
\ ..' '..'--enable=warning,style,performance,portability,information,missingInclude'
|
|
\ ..' '..(executable('getconf') ? '-j' .. systemlist('getconf _NPROCESSORS_ONLN')[0] : '')
|
|
let s:undo_compiler = 'unlet! g:c_cppcheck_params'
|
|
endif
|
|
|
|
exe 'CompilerSet makeprg=' .. escape('cppcheck --quiet'
|
|
\ ..' --template="{file}:{line}:{column}: {severity}: [{id}] {message} {callstack}"'
|
|
\ ..' '..get(b:, 'c_cppcheck_params', get(g:, 'c_cppcheck_params', (&filetype ==# 'cpp' ? ' --language=c++' : '')))
|
|
\ ..' '..get(b:, 'c_cppcheck_includes', get(g:, 'c_cppcheck_includes',
|
|
\ (filereadable('compile_commands.json') ? '--project=compile_commands.json' :
|
|
\ (!empty(glob('*'..s:slash..'compile_commands.json', 1, 1)) ? '--project='..glob('*'..s:slash..'compile_commands.json', 1, 1)[0] :
|
|
\ (empty(&path) ? '' : '-I')..join(map(filter(split(&path, ','), 'isdirectory(v:val)'),'shellescape(v:val)'), ' -I'))))),
|
|
\ ' \|"')
|
|
|
|
CompilerSet errorformat=
|
|
\%f:%l:%c:\ %tarning:\ %m,
|
|
\%f:%l:%c:\ %trror:\ %m,
|
|
\%f:%l:%c:\ %tnformation:\ %m,
|
|
\%f:%l:%c:\ %m,
|
|
\%.%#\ :\ [%f:%l]\ %m
|
|
|
|
exe get(s:, 'undo_compiler', '')
|
|
|
|
let &cpo = s:cpo_save
|
|
unlet s:cpo_save
|